Artifact Content
Not logged in

Artifact b31cedbd097b2a1d16151e6bd2fc9a6bf0d50a97:


apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'eclipse'

Properties props = new Properties()
props.load(new FileInputStream("../java-ilp-master/interledger_versioning.prop"))
Properties props_auxi = new Properties()
props_auxi.load(new FileInputStream("../java-ilp-master/external_library_versioning.prop"))

props.putAll(props_auxi);

group = 'org.interledger'
version =  props.java_ilp_ledger_simple_version




description = "Simple in-memory interledger implementation"

sourceCompatibility = 1.6
targetCompatibility = 1.6

jar {
    manifest {
        attributes 'Implementation-Title': 'Interledger Protocol Ledger Simple',
                   'Implementation-Version': version
    }
}

repositories {
    mavenLocal()
    maven { url "http://repo.maven.apache.org/maven2" }
    maven { url "https://jitpack.io" }
}

dependencies {
    compile     "org.interledger:java-ilp-core:${props.java_ilp_core_version}"
    compile     "org.javamoney:moneta:${props.moneta_version}"
    compile     "commons-lang:commons-lang:${props.commons_lang_version}"
    compile     "com.fasterxml.jackson.core:jackson-annotations:${props.jackson_annotations_version}"
    testCompile "junit:junit:${props.junit_version}"
    testCompile "org.hamcrest:hamcrest-core:${props.hamcrest_core_version}"
}

//Maven compatibility task:
task writePom  {
  doLast {
    pom {
        project {
            description project.description                        
            inceptionYear '2016'        
            properties {
                "project.build.sourceEncoding" "UTF-8"
                "maven.compiler.source" "1.6"
                "maven.compiler.target" "1.6"
            }                        
            licenses {
                license {
                    name 'The Apache Software License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    distribution 'repo'
                }
            }  
            developers {
                developer {
                    id "mrmx"
                    name "Manuel Polo"
                    email "mistermx@gmail.com"
                    organizationUrl "http://www.everis.com"
                }
                developer {
                    id "earizon"
                    name "Enrique Arizón Benito"
                    email "enrique.arizon.benito@everis.com"
                    organizationUrl "http://www.everis.com"
                }
            }
        }
        
    }.writeTo("pom.xml")
  }
}