Artifact Content
Not logged in

Artifact a6e8b49f3b3c3aaf5c5777d4332b6d947f47e404:


group = 'org.interledger'
description = 'Interledger SPSP client'
version = '1.0.0-SNAPSHOT'

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'checkstyle'

sourceCompatibility = 1.8
targetCompatibility = 1.8

jar {
    manifest {
        attributes 'Implementation-Title': description,
                   'Implementation-Version': version
    }
}

repositories {
    mavenCentral()
    maven { url "http://repo.spring.io/release" }
}

checkstyle {
    configFile file('google_checks.xml')
    toolVersion '7.1'
    showViolations = true
}

configurations.all {
    //Using SLF4J
    exclude group: "commons-logging", module: "commons-logging"
}

dependencies {

    compile project(":java-crypto-conditions")
    compile project(":java-ilp-core")
        
    compile("org.slf4j:jcl-over-slf4j:1.7.12")
     
    compile("org.springframework:spring-core:4.3.5.RELEASE")
    compile("org.springframework:spring-web:4.3.5.RELEASE")
    compile("org.springframework.boot:spring-boot-starter-web:1.4.3.RELEASE")

    // JSR-354 (javax.money) Reference implementation
    compile('org.javamoney:moneta:1.1')

    //JSON encoder
    compile("com.fasterxml.jackson.core:jackson-databind:2.8.5")
    compile("com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.8.5")
    
    compile("org.apache.httpcomponents:httpclient:4.5.2")

    testCompile("junit:junit:4.12")
    
    testCompile("org.springframework:spring-test:4.3.5.RELEASE")
}

//Maven compatibility task:
task writePom << {    
    pom {
        project {
            inceptionYear '2016'    
            properties {
                "project.build.sourceEncoding" "UTF-8"
                "checkstyle.config.location" "google_checks.xml"
                "checkstyle.consoleOutput" "true"
            }            
            licenses {
                license {
                    name 'The Apache Software License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    distribution 'repo'
                }
            }
            reporting  {
                plugins {
                    plugin {
                        groupId "org.apache.maven.plugins"
                        artifactId "maven-checkstyle-plugin"
                        version "2.17"
                    }                   
                }
            }
        }
    }.writeTo("pom.xml")
}